home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Apple II Magazines (DO)
/
Micro on the Apple Volume 2 (1981)(Micro Ink).zip
/
Micro on the Apple Volume 2 (1981)(Micro Ink).do
/
LIFESAVER.int
< prev
next >
Wrap
Text File
|
1996-12-24
|
5KB
|
154 lines
0 LOMEM:2500
1 REM ************************
2 REM * *
3 REM * APPLE LIFE-SAVER *
4 REM * GREGORY TIBBETTS *
5 REM * *
6 REM * LIFESAVER *
7 REM * *
8 REM * COPYRIGHT (C) 1981 *
9 REM * MICRO INK, INC. *
10 REM * CHELMSFORD, MA 01824 *
11 REM * ALL RIGHTS RESERVED *
12 REM * *
13 REM ************************
14 REM
16 DIM HEX$(30)
30 PRINT "<CTRL-D>BLOAD LIFE"
50 GOTO 800
60 POKE -16302,0:COLOR= 0:FOR K=40 TO 47
70 HLIN 0,39 AT K:NEXT K
80 KX=PDL (0)-10:IF KX>240 THEN KX=KX1:IF KX<0 THEN KX=0
90 K1=KX*6:K2=KX*2:K3=500/(K1+50)+1
100 FOR I=1 TO K3
110 CALL GEN
120 FOR K=1 TO K1:NEXT K
130 CALL MOP
140 FOR K=1 TO K2:NEXT K
150 NEXT I
160 GOTO 80
170 FOR I=1 TO SIZE:COLOR= 11
180 X=XCTR+X(I):Y=YCTR+Y(I)
190 IF X<0 OR X>39 OR Y<0 OR Y>39 THEN 1210
200 PLOT X,Y:NEXT I
210 RETURN
220 FOR I=I1 TO I2:FOR J=J1 TO J2
230 COLOR= 11:IF RND (L) THEN COLOR= 0
240 PLOT I,J
250 NEXT J:NEXT I
260 GOTO 60
270 FOR I=1 TO SIZE
280 X=Y(I):Y=X(I)
290 IF Y(I) THEN X=X*-1
300 X(I)=X:Y(I)=Y
310 NEXT I:RETURN
320 FOR I=1 TO SIZE
330 X(I)=X(I)*-1:Y(I)=Y(I)*-1
340 NEXT I:RETURN
350 FOR I=1 TO SIZE
360 IF XAX THEN 380
370 X=X(I):Y=Y(I)*-1:GOTO 390
380 Y=Y(I):X=X(I)*-1
390 X(I)=X:Y(I)=Y:NEXT I
400 RETURN
410 PRINT D$;"OPEN";A$
420 PRINT D$;"READ";A$
430 FOR I=1 TO 255
440 INPUT X(I),Y(I)
450 IF X(I)=99 OR Y(I)=99 THEN 470
460 NEXT I
470 SIZE=I-1
480 PRINT D$;"CLOSE";A$
490 IF ROT THEN GOSUB 270
500 IF HALF THEN GOSUB 320
510 IF REV THEN GOSUB 350
520 GOSUB 170
530 HALF=0:ROT=0:REV=0:XAX=0:SIZE=0
540 RETURN
550 PRINT D$;"OPEN";A$
560 PRINT D$;"DELETE";A$
570 PRINT D$;"OPEN";A$
580 PRINT D$;"WRITE";A$
590 FOR I=1 TO SIZE
600 PRINT X(I)
610 PRINT Y(I)
620 NEXT I
630 PRINT D$;"CLOSE";A$
640 RETURN
650 FOR I=1 TO 255
660 INPUT X,Y
670 IF X=99 OR Y=99 THEN 720
680 IF X<0 OR X>39 OR Y<0 OR Y>39 THEN 700
690 X(I)=X-XCTR:Y(I)=Y-YCTR:GOTO 710
700 PRINT "OUT OF RANGE!":GOTO 660
710 NEXT I
720 X(I)=99:Y(I)=99
730 SIZE=I
740 RETURN
750 INPUT "INPUT X,Y",X,Y
760 IF X=99 OR Y=99 THEN 60
770 IF X<0 OR X>39 OR Y<0 OR Y>39 THEN 790
780 COLOR= 11:PLOT X,Y:GOTO 750
790 PRINT "OUT OF RANGE!":GOTO 750
800 TEXT
810 DIM X(255),Y(255),A$(50),B$(2),D$(1)
820 GEN=2088:MOP=2265:K1=1:K2=1:D$="<CTRL-D>":REM D$=CNTRL D
830 CALL -936:VTAB 5:TAB 9:PRINT "CONWAYS GAME OF LIFE":FOR I=1 TO 700:NEXT I
840 GR
850 PRINT "DO YOU WISH TO: 1.PLAY OR 2.CREATE"
860 INPUT "A NEW PATTERN FILE (1/2).",C1
870 IF C1=2 THEN 1140
880 INPUT "SPEED=PDL(0): SET DEFAULT (0-255)",KX1
890 PRINT "DO YOU WISH 1.RANDOM PATTERN 2.PATTERN"
900 INPUT "FROM DISK OR 3.STANDARD: (1/2/3)",C1
910 IF C1=3 THEN 990
920 IF C1=2 THEN 1010
930 INPUT "X DIRECTION LIMITS ",I1,I2
940 IF I1<0 OR I2>39 OR I1>I2 THEN 930
950 INPUT "Y DIRECTION LIMITS ",J1,J2
960 IF J1<0 OR J2>39 OR J1>J2 THEN 950
970 INPUT "ONE IN 'N' CELLS WILL LIVE:ENTER N",L
980 GOTO 220
990 PRINT "ENTER YOUR PATTERN (X,Y):99,99 EXITS"
1000 GOTO 750
1010 INPUT "WHAT FIGURE NAME",A$
1020 INPUT "ENTER CENTER COORD'S (X,Y)",XCTR,YCTR
1030 INPUT "ENTER ROTATION (0/90/180/270)",ROT
1040 IF ROT=180 OR ROT=270 THEN HALF=1
1050 IF ROT=90 OR ROT=270 THEN ROT=1
1060 IF ROT<>1 THEN ROT=0
1070 INPUT "ENTER 1.REVERSED OR 2.STANDARD (1/2)",REV
1080 IF REV>1 THEN REV=0:IF NOT REV THEN 1110
1090 INPUT "REVERSE ON 1.X-AXIS OR 2.Y-AXIS (1/2)",XAX
1100 IF XAX>1 THEN XAX=0
1110 GOSUB 410
1120 INPUT "ANOTHER FIGURE (Y/N)",B$:IF B$="N" THEN 60
1130 PRINT "CAUTION:FIGURES MAY OVERWRITE!":GOTO 1010
1140 INPUT "ENTER CENTER COORD'S (X,Y)",XCTR,YCTR
1150 PRINT "ENTER ALL LIVE CELLS (X,Y): 99,99 EXITS"
1160 GOSUB 650
1170 INPUT "ENTER NAME FOR THIS FIGURE",A$
1180 GOSUB 550
1190 PRINT "TESTING":GOSUB 410
1200 GOTO 60
1210 PRINT "PLOT ABORTED/FIGURE WENT OFF SCREEN"
1220 PRINT "MOVE CENTERPOINT:X AND Y WHEN ABORTED"
1230 PRINT "WERE ";X;",";Y:POP :POP
1240 IF I=1 THEN 1020:IE=I-1:COLOR= 0:FOR I=1 TO IE
1250 PLOT X(I)+XCTR,Y(I)+YCTR:NEXT I:GOTO 1020
1260 REM ADAPTATION BY GREG TIBBETTS OF RICHARD SUITOR'S PROGRAM IN "BEST OF MICRO" VOLUME II 1979
1270 REM LINES 0-50 PROGRAM SET-UP
1280 REM 60-160 SPEED AND GENERATION
1290 REM 170-210 GENERAL PLOT SUBR.
1300 REM 220-260 RANDOM PLOT SUBR.
1310 REM 270-340 ROTATION SUBR'S.
1320 REM 350-400 REVERSAL SUBR.
1330 REM 410-540 DISK READ SUBR.
1340 REM 550-740 DISK WRITE SUBR'S.
1350 REM 750-790 STANDARD INPUT SUBR
1360 REM 800-840 INITIALIZATION
1370 REM 850-920 MODE SELECTION
1380 REM 930-1200 USER INPUT/SELECT
1390 REM 1210-1250 PLOT ABORT SUBR.
10000 END